3. LoRa Multipunto – HELTEC CubeCell SemiDuplex.ino

Como cada dispositivo contiene solo un radio, la comunicación en dos sentidos puede habilitarse en modo SemiDuplex. Las funciones de transmisión y recepción se alternan.

Resultados

TX Paquete "213110" , tamano 6 bytes , proximo en 8118 ms 
    RX Paquete "312139" , tamanio 6, Rssi -22 
TX Paquete "213111" , tamano 6 bytes , proximo en 8429 ms 
    RX Paquete "312140" , tamanio 6, Rssi -23 
TX Paquete "213112" , tamano 6 bytes , proximo en 9397 ms 

Instrucciones

/* LoRa TRANSMITE/RECIBE Semi Duplex / Half-Duplex
 * Referencia: https://github.com/HelTecAutomation/ASR650x-Arduino
*/
#include "LoRaWan_APP.h"
#include "Arduino.h"

#ifndef LoraWan_RGB    // LED placa
#define LoraWan_RGB 0
#endif

// LoRa Parametros 
#define RF_FREQUENCY       915E6     // Hz
#define TX_OUTPUT_POWER    14        // dBm
#define LORA_BANDWIDTH     0         // [0: 125 kHz, 1: 250 kHz,
                                     //  2: 500 kHz, 3: Reserved]
#define LORA_SPREADING_FACTOR   7    // [SF7..SF12]
#define LORA_CODINGRATE         1    // [1: 4/5,  2: 4/6,
                                     //  3: 4/7,  4: 4/8]
#define LORA_PREAMBLE_LENGTH    8    // Same for Tx and Rx
#define LORA_SYMBOL_TIMEOUT     0    // Symbols
#define LORA_FIX_LENGTH_PAYLOAD_ON  false
#define LORA_IQ_INVERSION_ON        false
#define RX_TIMEOUT_VALUE            1000
#define BUFFER_SIZE                 30 // Define the payload size here
char txpacket[BUFFER_SIZE];          // cadena de caracteres
char rxpacket[BUFFER_SIZE];
static RadioEvents_t RadioEvents;

void OnTxDone( void );     // Tx completada
void OnTxTimeout( void );  // Tx fuera de tiempo
void OnRxDone( uint8_t *payload, uint16_t size, int16_t rssi, int8_t snr );

byte modoOperacion = 0; // 0:RX 1:TX
bool sleepMode = false;
int16_t txNumero;
int16_t Rssi,rxSize;

// Direcciones por dispositivo
byte dir_local   = 21; // Dispositivo envia
byte dir_destino = 31; // Dispositivo recibe

// tiempo entre Tx de datos o lecturas de sensor
long tiempo_antes     = 0;
long tiempo_intervalo = 7000;
long tiempo_espera = tiempo_intervalo + random(3000);

void setup() {
  Serial.begin(115200);
  txNumero=10; Rssi=0;

  RadioEvents.TxDone = OnTxDone;
  RadioEvents.TxTimeout = OnTxTimeout;
  RadioEvents.RxDone = OnRxDone;
  Radio.Init( &RadioEvents );

  Radio.SetChannel( RF_FREQUENCY );
  Radio.SetTxConfig( MODEM_LORA, TX_OUTPUT_POWER, 0, LORA_BANDWIDTH,
                     LORA_SPREADING_FACTOR, LORA_CODINGRATE,
                     LORA_PREAMBLE_LENGTH, LORA_FIX_LENGTH_PAYLOAD_ON,
                     true, 0, 0, LORA_IQ_INVERSION_ON, 3000 );
  Radio.SetRxConfig( MODEM_LORA, LORA_BANDWIDTH, LORA_SPREADING_FACTOR,
                     LORA_CODINGRATE, 0, LORA_PREAMBLE_LENGTH,
                     LORA_SYMBOL_TIMEOUT, LORA_FIX_LENGTH_PAYLOAD_ON,
                     0, true, 0, 0, LORA_IQ_INVERSION_ON, true );
  modoOperacion=0;  // 0:RX 1:TX 2:LOWPOWER
}

void loop(){
  // Intervalos entre mensajes
  long tiempo_ahora   = millis();
  long t_transcurrido = tiempo_ahora - tiempo_antes;
  if (t_transcurrido >= tiempo_espera){
    tiempo_antes = millis();
    tiempo_espera = tiempo_intervalo + random(3000);
    modoOperacion=1; // 0:RX 1:TX
  }else{
    modoOperacion=0; // 0:RX 1:TX
  }
  
  switch(modoOperacion) { // 0:RX 1:TX 2:LOWPOWER
    case 0:
      Radio.Rx( 0 );   
      modoOperacion=2;  //LOWPOWER;
      break;
    case 1:
      delay(500);
      transmiteMsg();
      modoOperacion=0;
      break;
    case 2:
      lowPowerHandler();
      modoOperacion=0;
      break;
    default:
      break;
  }
  turnOnRGB(0,0); // LED apaga
  delay(100);
  Radio.IrqProcess( );
}

Procedimiento de transmisión de paquete LoRa

void transmiteMsg( void ) {
  turnOnRGB(COLOR_SEND,0); // LED de placa
  // Paquete a transmitir
  sprintf(txpacket,"%d",dir_local);
  sprintf(txpacket+strlen(txpacket),"%d",dir_destino);
  sprintf(txpacket+strlen(txpacket),"%d",txNumero); //añade número paquete a txpacket

  // Mensaje a pantalla
  Serial.printf("\rTX Paquete \"%s\" , tamano %d bytes\r",
                txpacket, strlen(txpacket));
  Serial.printf("\r , proximo en %d ms \r\n",
                tiempo_espera);
  
  // Transmite paquete LoRa
  Radio.Send( (uint8_t *)txpacket, strlen(txpacket) );

  txNumero = txNumero + 1;  // cuenta paquete
  if (txNumero>=99){
    txNumero = 0;           // reinicia contador
  }
  modoOperacion=2;//LOWPOWER;
}

void OnTxDone( void ) {
  turnOnRGB(0,0);
  modoOperacion=0;
}

void OnTxTimeout( void ) {
  Radio.Sleep( );
  Serial.println("TX Timeout......");
  modoOperacion=1;
}

Procedimiento de recepción de paquete LoRa

void OnRxDone( uint8_t *payload, uint16_t size, int16_t rssi, int8_t snr ) {
  turnOnRGB(COLOR_RECEIVED,0);
  Rssi = rssi;     // nivel de recepcion
  rxSize = size;
  memcpy(rxpacket, payload, size );
  rxpacket[size]='\0';  //añade fin de cadena

  Radio.Sleep( );

  Serial.printf("\r    RX Paquete \"%s\" , tamanio %d, Rssi %d \r\n",
                rxpacket,rxSize,Rssi);
}