Dispositivos WiFi – índices

Esquematicos

IoT WiFi Dispositivo Sensor Puerta-Ventana

El dispositivo sensor de Puerta Ventana se implementa usando tres componentes principales:

2.1 Sensor magnético

2.2 Microcontrolador con Wifi: ESP8266 – versión ESP01

ESP8266 versión ESP01

2.3. Instrucciones en IDE Arduino

ESP8266 en Arduino IDE

Los pasos de integración de los componentes se describen en la sección:

IoT WiFi Sensor Puerta-Ventana


3. Complementos

En el proceso, para realizar los diagramas de circuito, conexiones con protoboard y placas PCB se utiliza el programa Fritzing que es de software abierto.

Fritzing – Partes adicionales

3.5 IoT WiFi Interruptor-Tomacorriente: Esquemático ESP01-Config

También posible construir una placa con los elementos necesarios para controlar el modo de operación del Módulo ESP-01 por medio de un DIP-Switch:

  • Modo Operación:  DIP-switch en 0111
  • Modo Programación: DIP-Switch en 1000

La operación es semejante al presentado en ésta sección, la diferencia es que no se requiere retirar el ESP01 de la placa. De ésta manera no se requiere retirar el módulo ESP-01 de la placa para realizar la carga del archivo.ino con la programación con un USB-TTL.

1. Esquemático con ESP01

2. Ensamble en Protoboard

3. Circuito impreso – PCB

4. Implementación en Placa perforada

Realizado para verificar las dimensiones y espacio usados en el diseño de la PCB. La versión es previa a la mostrada en la sección 3.

 

4.4 IoT WiFi Sensor a Batería/Temp-Hum: Archivo.ino

1. Instrucciones en Arduino IDE

El modelo ESP-07 dispone de suficientes pines que permiten incorporar las funciones de programación usando pines de una sola función. Por lo que se facilita el diseño.

Modo Ahorro de Energía

Las instrucciones se desarrollan en la parte de configuración Setup() en lugar del lazo, Loop(), debido a que se utiliza el modo de ahorro de energía (deep-sleep).

2 Funciones para sensores y actuadores

Se han separado en funciones las instrucciones para el sensor de batería y temperatura-humedad.

/* Sensor de Temperatura y Humedad DHT11
Sensor de Estado de Batería
Funcionamiento con Batería
Para usar, se debe actualizar las secciones de:
 - WIFI datos para conexión a Router
 - MQTT: Servidor MQTT 
 - MQTT: identificador de dispositivo y topics
Se está usando ESP8266-07, pero para programar,
usar Placa:ESP8285
*/
#include <ESP8266WiFi.h>
#include <PubSubClient.h>
#include <dht.h>

// WIFI datos para conexión a Router
const PROGMEM char* ssid = "iotirni19";
const PROGMEM char* password = "anera2018";

// MQTT: Servidor MQTT 
const PROGMEM char* MQTT_SERVER_IP = "192.168.10.100";
const PROGMEM uint16_t MQTT_SERVER_PORT = 1883;
const PROGMEM char* MQTT_USER = "username";
const PROGMEM char* MQTT_PASSWORD = "password";

// MQTT: identificador de dispositivo y topics
const PROGMEM char* MQTT_CLIENT_ID = "Temp_humedad01";
const PROGMEM char* MQTT_SENSOR_TOPIC_T = "oficina/DHT_Temperatura";
const PROGMEM char* MQTT_SENSOR_TOPIC_H = "oficina/DHT_Humedad";
const PROGMEM char* MQTT_SENSOR_TOPIC_B = "oficina/DHT_Bateria";
const PROGMEM char* MQTT_SENSOR_TOPIC_BS = "oficina/DHT_BatSistema";
char MQTT_SENSOR_STATE_T[10] = "0"; // inicializa
char MQTT_SENSOR_STATE_H[10] = "0"; // inicializa
char MQTT_SENSOR_STATE_B[10] = "0"; // inicializa
char MQTT_SENSOR_STATE_BS[10] = "0"; // inicializa

// LED monitor interno
//ESP01-pin=1, ESP07-pin=2
const PROGMEM uint8_t LED_pin = 2; 

// Sensor de Temperatura&Humedad
dht DHT;
#define DHT11_PIN 12

// Bateria
#define bat_estado A0
const PROGMEM uint8_t bat_activa = 4;

// tiempo de dormir
int durmiendo = 5; //segundos

WiFiClient wifiClient;
PubSubClient client(wifiClient);

void setup() {
    // Conexion serial
    Serial.begin(9600);//74880);
    Serial.setTimeout(2000);

    // SENSOR Temperatura&Humedad
    //pinMode(DHT11_PIN, INPUT);

    // SENSOR Bateria
    pinMode(bat_activa, OUTPUT);
    digitalWrite(bat_activa, LOW);

    // LED monitor
    pinMode(LED_pin, OUTPUT);
    // LEDactivaestado();

    // Inicia redes
    if(WiFi.status() != WL_CONNECTED){
        inicia_wifi();
        }
    if (!client.connected()){
        inicia_mqtt();
        }
    client.loop();
    
    // espera inicializar serial
    while(!Serial) { }
    // actividad al despertar
    Serial.println();
    Serial.println("despertando");
    
    // lectura de sensores
    SensorTempHum();
    SensorBateria();

    // a dormir
    Serial.println("A dormir por " + String(durmiendo) + " segundos");
    ESP.deepSleep(durmiendo*1e6); //en microsegundos
}

void loop() {
    // modo sleep usa función setup
}

void SensorTempHum(){
    int chk = DHT.read11(DHT11_PIN);
    float temperatura = DHT.temperature;
    float humedad = DHT.humidity;
    Serial.println("Temperatura,Humedad: ");
    Serial.print(temperatura);
    Serial.print(",");
    Serial.println(humedad);
    client.publish(MQTT_SENSOR_TOPIC_T, 
                    String(temperatura).c_str(), 
                    true);
    client.publish(MQTT_SENSOR_TOPIC_H, 
                    String(humedad).c_str(), 
                    true);
    delay(1000);
}
void SensorBateria(){

    // Activar, Leer, Desactivar, publicar
    digitalWrite(bat_activa, HIGH);
    
    float bateria = analogRead(A0)*(57/10)/1024;
    int bat_sistema = ESP.getVcc()*100/65535;
    //delay(5000); // observar cambio
    digitalWrite(bat_activa, LOW);
    
    Serial.println("Bateria (V), sistema (%):");
    Serial.print(bateria);
    Serial.print(",");
    Serial.println(bat_sistema);
    
    client.publish(MQTT_SENSOR_TOPIC_B,
                    String(bateria).c_str(),
                    true);
    client.publish(MQTT_SENSOR_TOPIC_BS,
                    String(bat_sistema).c_str(),
                    true);
    delay(10);
}

void inicia_wifi() {
    // conexion WiFi
    Serial.print("\n Conectando a ");
    Serial.println(ssid);
    WiFi.begin(ssid, password);
    int cuenta = 0;
    while (WiFi.status() != WL_CONNECTED){
        Serial.print(".");
        cuenta = cuenta+1;
        if (cuenta>=40){
            Serial.println();
            cuenta = 0;}
        // LED interno enciende en LOW
        digitalWrite(LED_pin, LOW);
        delay(250);
        digitalWrite(LED_pin, HIGH);
        delay(250);
        }
    Serial.print("\n WiFi conectado \n Dirección IP: ");
    Serial.println(WiFi.localIP());
    delay(10);
}

void inicia_mqtt(){
    client.setServer(MQTT_SERVER_IP, MQTT_SERVER_PORT);
    //client.setCallback(callback);
    while (!client.connected()) {
        //Serial.println("\n Conectando a MQTT ");
        if (client.connect(MQTT_CLIENT_ID, MQTT_USER, MQTT_PASSWORD)) {
            Serial.println(" MQTT conectado");  
        } else {
            Serial.print("Falló, estado: ");
            Serial.print(client.state()); 
            Serial.print(" , reintento en 5 segundos");
            // LED interno enciende en LOW
            for (int i=0;i<=5;i=i+1){
                digitalWrite(LED_pin, LOW);
                delay(600);
                digitalWrite(LED_pin, HIGH);
                delay(400);
            }
        }
    }
}

5.3 IoT WiFi Control Remoto IR: Archivo.ino

Instrucciones

Las instrucciones enfocadas en cada sensor o actividad se resumen en funciones, tratando de mantener la simplicidad del lazo principal.

Las instrucciones incorporan las siguientes características:

  • el boton config_IR, una vez presionado espera hasta recibir una señal infraroja que se lee, y graba.
  • el Envío de la señal se realiza con la instrucción MQTT o  desde Home Assistant
  • Usa el LED_LeeIR  como indicador de estado de lectura o activación de control remoto.
  • Se emite la señal de control mediante la variable senal_ONOFF
  • Se controla el estado de lectura del sensor/decodificador infrarojo mediante MQTT, y la respuesta se emite a la conexión serial.
  • La temperatura y humedad se actualizan con el parametro «intervalo» cuyo primer número es minutos
/* ESP8266 IRremoteESP8266: Receptor Infrarojo
 * edelros@espol.edu.ec
 * Debe usar un sensor detector/demodulador conectado al Receptor_Pin.
 *   Based on Mark Szabo's Version 0.2 June, 2017 and
 *   Ken Shirriff's IrsendDemo Version 0.1 July, 2009
 *   https://github.com/markszabo/IRremoteESP8266 
*  Para usar, actualice las secciones de:
 *  - WIFI:Router, MQTT:Servidor, MQTT:Dispositivo
 *  ESP-01 al usar GPIO1 y GPIO3,(Tx,Rx), NO USE Serial.print()
*/
#include <ESP8266WiFi.h>
#include <PubSubClient.h>

#include <IRremoteESP8266.h>
#include <IRrecv.h>
#include <IRutils.h>
#include <IRsend.h>

#include <EEPROM.h>

#include <DHT.h>

// WIFI: conexión a Router
char* ssid = "giotirni20";
char* password = "Anera2020@";

// MQTT: Servidor
char* MQTT_IP = "192.168.10.50";
uint16_t MQTT_puerto = 1883;
char* MQTT_usuario = "usuarioprueba";
char* MQTT_contrasena = "usuarioclave";

// MQTT: Dispositivo Interruptor
char* MQTT_ID = "oficina_CtrlIR01";
char* MQTT_TOPIC = "oficina/CtrlIR01/estado";
char* MQTT_COMMAND = "oficina/CtrlIR01/cambia";

char* MQTT_TOPIC_T = "oficina/CtrlIR01/temperatura";
char* MQTT_TOPIC_H = "oficina/CtrlIR01/humedad";
char* MQTT_COMMAND_DHT = "oficina/CtrlIR01/actualiza";

char* MQTT_TOPIC_LeeIR = "oficina/CtrlIR01/leer";
char* MQTT_COMMAND_LeeIR = "oficina/CtrlIR01/grabar";

char MQTT_SensorEstado[10] = "OFF";
char MQTT_ActuadorEstado[10] = "OFF";
char MQTT_DHT_T[6] = "25"; // inicializa
char MQTT_DHT_H[6] = "50"; // inicializa
char MQTT_LeeIR[6] = "0"; // inicializa
volatile boolean mqtt_desconectado = true;

char* sensor_ON  = "ON";
char* sensor_OFF = "OFF";

// Actuador Control Remoto Emisor LED-IR en GPIO14
const uint8_t emisorIR_pin = 14;
uint32_t senal_ONOFF = 0xFF5AA5; // código de control
volatile boolean actuador_estado = false;
volatile boolean actuador_bandera = false;

// Sensor IR en GPIO05
const uint8_t receptorIR_pin = 5;
volatile boolean LeerIR_estado = false;
volatile boolean LeerIR_bandera = false;

// Boton de lectura y emitir IR
const uint8_t config_pin = 12;
const uint8_t emitir_pin = 0;

// LED monitor //interno: ESP01-pin=1, ESP07-pin=2
const uint8_t LED_pin=13;
const uint8_t LED_LeerIR = 2;

// Mensajes por Puerto Serial
volatile boolean serial_msg = true;

// Control de tiempo transcurrido entre lecturas temperatura
unsigned long ahora = millis();
const long intervalo = 5*60*1000;//minutos*60s*1000ms
unsigned long antes = ahora-intervalo-1; //leer al inicio

// Clientes WiFi y MQTT
WiFiClient wifiClient;
PubSubClient mqttclient(wifiClient);

// Receptor y Emisor Infrarojos
IRrecv irrecv(receptorIR_pin);
decode_results lecturaIR;
IRsend irsend(emisorIR_pin);

// Sensor de Temperatura&Humedad
#define DHTPIN 4
#define DHTTYPE   DHT11
DHT dht(DHTPIN, DHTTYPE);

void setup() {
  Serial.begin(74880);//74880, 115200
  while (!Serial){delay(50);}
  
  // SENSOR IR // inicia receptor IR
  irrecv.enableIRIn(); 
  pinMode(LED_LeerIR, OUTPUT);
  Leer_Activaestado();
    
  // ACTUADOR IR // inicia emisor IR
  pinMode(emisorIR_pin, OUTPUT); 
  irsend.begin();

  // SENSOR Temperatura&Humedad
  dht.begin();
  
  // LED monitor, Enciende en LOW
  pinMode(LED_pin, OUTPUT);

  // Memoria lectura y escritura
  EEPROM.begin(64); //eeprom maximo 512 posiciones
  codigo_leermem();

  // Boton de lectura de código IR
  pinMode(config_pin, INPUT);
  attachInterrupt(digitalPinToInterrupt(config_pin),LeerActivado,CHANGE);

  // Boton de Emisor de código IR
  pinMode(emitir_pin, INPUT);
  attachInterrupt(digitalPinToInterrupt(emitir_pin),IR_Activado,CHANGE);
  
  // conexión WIFI y MQTT
  inicia_wifi();
  if (WiFi.status() == WL_CONNECTED){
    inicia_mqtt();
    }
  }

void loop() {
  // enviar señal IR
  if (actuador_bandera){
    irsend.sendNEC(senal_ONOFF ,32);
    // parpadeo
    digitalWrite(LED_LeerIR, LOW);
    delay(300);
    digitalWrite(LED_LeerIR, HIGH);
    delay(200);
    digitalWrite(LED_LeerIR, LOW);
    delay(300);
    digitalWrite(LED_LeerIR, HIGH);
    delay(200);
    // deja en estado anterior el LED Leer_IR
    Leer_Activaestado();
    publica_estado();
    actuador_bandera = false;
    
    if (serial_msg==true){
      Serial.print("\n Señal IR enviada: ");
      serialPrintUint64(senal_ONOFF, HEX);
      Serial.println("");
      }

    }
  yield(); // procesa wifi

  // Sensor IR, leer código
  if(LeerIR_bandera){
    if (irrecv.decode(&lecturaIR)) {
      // conversión a texto
      uint64_t numero = lecturaIR.value;
      unsigned long parte1 = (unsigned long)((numero & 0xFFFF0000) >> 16 );
      unsigned long parte2 = (unsigned long)((numero & 0x0000FFFF));
      String texto = String(parte1, HEX) + String(parte2, HEX);
      texto.toUpperCase();
      senal_ONOFF = lecturaIR.value;
      
      // Escribe a memoria EEPROM    
      // escribe a eeprom
      texto = texto+";"; //marca fin de texto
      int n = texto.length();
      int posicion = 0;
      int i = posicion;
      while(i<n){
        EEPROM.write(i,texto[i]);
        i=i+1;
        }
      EEPROM.commit();
      irrecv.resume();
       
      LeerIR_bandera = false;
      LeerIR_estado = false;

      publica_estado();
      Leer_Activaestado();
      
      if (serial_msg==true){
        Serial.print("\n lecturaIR:       ");
        // print() & println() no maneja enteros largos(uint64_t)
        serialPrintUint64(lecturaIR.value, HEX);
        Serial.println("");
        Serial.print(" grabado en memoria:   ");
        Serial.println(texto);
        }
    }
  }

  yield(); // procesa wifi
  
  // lectura Temperatura,Humedad
  unsigned long ahora = millis();
  unsigned long transcurre = ahora-antes;
  if (transcurre>=intervalo){
    antes = ahora;
    delay(50);
    // calibrar con una referencia más precisa
    // modo simple: resta factor de corrección=5
    float temperatura = dht.readTemperature();
    float humedad = dht.readHumidity();
    // convierte a texto mqtt; a 4 dígitos, 2 decimales
    dtostrf(temperatura, 4, 2, MQTT_DHT_T);  
    dtostrf(humedad, 4, 2, MQTT_DHT_H);
    publica_estado();
    
    if (serial_msg==true){
      Serial.print("\n tiempo: ");
      Serial.println(transcurre);
      Serial.print(" Temperatura,Humedad: ");
      Serial.print(MQTT_DHT_T);
      Serial.print(" , ");
      Serial.println(MQTT_DHT_H);
      Serial.println();
      }
    }
    
  yield(); // procesa wifi
  
  if (WiFi.status() != WL_CONNECTED){
    inicia_wifi();
    }else{
    if (mqttclient.connected()==false){
        mqtt_desconectado = true;
        inicia_mqtt(); // reintento
      }
    if (mqttclient.connected()==true){
      if (mqtt_desconectado==true){
        publica_estado();
        mqtt_desconectado=false;
        }
      mqttclient.loop();
      }
    }
  yield(); // procesa wifi
}

void codigo_leermem(){
  // lectura desde eeprom, codigo on/off
  int posicion = 0;
  int n = posicion+10;
  String codigotxt = "";
  char simbolo;
  int i = posicion;
  while(i<n){
    simbolo = char(EEPROM.read(i));
    if (simbolo!=';'){
      codigotxt = codigotxt+String(simbolo);
      }else{
        i=n; // terminar lectura antes
      }
    i=i+1;
    }
  // conversión de codigotxt a HEX
  char codigochar[64];
  codigotxt.toCharArray(codigochar, n);
  uint32_t codigoIRhex = strtoul(codigochar, 0, 16);
  // actualiza variable
  senal_ONOFF = codigoIRhex;
  if (serial_msg==true){
    Serial.print("texto leido:     ");
    Serial.println(codigotxt);
    Serial.print("codigo IR eprom: ");
    // print() & println() no maneja enteros largos(uint64_t)
    serialPrintUint64(senal_ONOFF, HEX);
    Serial.println("\n");
    }
  }

// ISR interrupción activada
ICACHE_RAM_ATTR void LeerActivado(){
  // evita repeticiones por rebotes del botonera
  if (LeerIR_bandera==false){
    LeerIR_bandera = true;
    LeerIR_estado = true;
    Leer_Activaestado();
    publica_estado();
    if (serial_msg){
      Serial.println(" Leer IR activado...");
      }
    }
  }
ICACHE_RAM_ATTR void IR_Activado(){
  // evita repeticionese por rebotes del botonera
  if (actuador_bandera ==false){
    actuador_bandera = true;
    if (actuador_estado == true) {
      actuador_estado = false;
      }else{
      actuador_estado = true;
      }
    publica_estado();
    if (serial_msg){
      Serial.println(" IR_envío activado...");
      }
    }
  }

// Actuador activar estado
void Leer_Activaestado(){
    if (LeerIR_estado){
      // ACTUADOR ACTIVA EN LOW
      // LED actuador ilumina en apagado
      digitalWrite(LED_LeerIR, LOW);
    }else{
      digitalWrite(LED_LeerIR, HIGH);
    }
  }

// Publicar el estado del dispositivo
void publica_estado() {
    if (actuador_estado){
      snprintf (MQTT_ActuadorEstado,10, sensor_ON);
    }else{
      snprintf (MQTT_ActuadorEstado,10, sensor_OFF);
    }
    if (LeerIR_estado){
      snprintf (MQTT_LeeIR,10, sensor_ON);
    }else{
      snprintf (MQTT_LeeIR,10, sensor_OFF);
    }
    if (mqttclient.connected()==true){
      mqttclient.publish(MQTT_TOPIC,MQTT_ActuadorEstado,true);
      mqttclient.publish(MQTT_TOPIC_LeeIR,MQTT_LeeIR,true);
      mqttclient.publish(MQTT_TOPIC_T,MQTT_DHT_T,true);
      mqttclient.publish(MQTT_TOPIC_H,MQTT_DHT_H,true);
    }else{
      mqtt_desconectado = true;
    }
}

void inicia_wifi(){
  int intentos = 10;
  int cuenta = 0;

  if (serial_msg){
    Serial.print(" WIFI Conectando a ");
    Serial.println(ssid);
    }
  WiFi.mode(WIFI_STA);
  WiFi.begin(ssid, password);
  
  while ((WiFi.status() != WL_CONNECTED) && (cuenta<intentos)){
    if (serial_msg){
      Serial.print(".");
      }
    cuenta = cuenta+1;
    // Parpadeo de Monitor enciende en LOW
    digitalWrite(LED_pin, LOW);
    delay(300);
    digitalWrite(LED_pin, HIGH);
    delay(200);
    }
  if (serial_msg){
    //Fin de "..."
    Serial.println();
    if (WiFi.status() == WL_CONNECTED){
      Serial.print(" Estado: ");
      Serial.println(WiFi.status());
      Serial.print(" MAC: ");
      Serial.println(WiFi.macAddress());
      Serial.print(" IP: ");
      Serial.println(WiFi.localIP());
      Serial.print(" RSSI: ");
      Serial.println(WiFi.RSSI());
      Serial.println();
      }
    if (WiFi.status() != WL_CONNECTED){
      WiFi.printDiag(Serial);
      Serial.println();
      }
    }
  }

void inicia_mqtt(){
  int intentos = 2;
  int cuenta = 0;
  
  if (serial_msg){
    Serial.print(" MQTT Conectando a ");
    Serial.println(MQTT_IP);
    }
  
  mqttclient.setServer(MQTT_IP, MQTT_puerto);
  mqttclient.connect(MQTT_ID, MQTT_usuario, MQTT_contrasena);
  mqttclient.setCallback(callback);
  
  while (!mqttclient.connected() && (cuenta<intentos)) {

    if (serial_msg){
      Serial.print(".");
    }
    
    cuenta = cuenta + 1;
    // Parpadeo de Monitor enciende en LOW
    digitalWrite(LED_pin, LOW);
    delay(200);
    digitalWrite(LED_pin, HIGH);
    delay(200);
    }
  publica_estado();
  mqttclient.subscribe(MQTT_COMMAND);
  mqttclient.subscribe(MQTT_COMMAND_LeeIR);
  mqttclient.subscribe(MQTT_COMMAND_DHT);
  
  if (serial_msg){
    //Fin de "..."
    Serial.println();
    Serial.print(" MQTT Conectado: ");
    Serial.println(mqttclient.connected());
    Serial.print(" MQTT Estado: ");
    Serial.println(mqttclient.state());
    }
  }

// llega mensaje MQTT
void callback(char* p_topic, byte* p_payload, unsigned int p_length) {
  // convierte a texto
  String payload;
  for (uint8_t i = 0; i < p_length; i++) {
    payload.concat((char)p_payload[i]);
    }
  // revisa mensaje por topico
  if (String(MQTT_COMMAND).equals(p_topic)) {
    if (payload.equals(String(sensor_ON))) {
      if (actuador_estado != true) {
        actuador_estado = true;
        }
      }
    if (payload.equals(String(sensor_OFF))) {
      if (actuador_estado != false) {
          actuador_estado = false;
        }
      }
    Leer_Activaestado();
    publica_estado();
    actuador_bandera = true;
    }

  if (String(MQTT_COMMAND_LeeIR).equals(p_topic)) {
    if (payload.equals(String(sensor_ON))) {
      if (LeerIR_estado != true) {
        LeerIR_estado = true;
        }
      }
    if (payload.equals(String(sensor_OFF))) {
      if (LeerIR_estado != false) {
          LeerIR_estado = false;
        }
      }
    LeerIR_bandera = true;
    Leer_Activaestado();
    publica_estado();
    }
  if (String(MQTT_COMMAND_DHT).equals(p_topic)) {
    antes = antes-(intervalo+2);
    }
  }

5.2 IoT WiFi Control Remoto IR: Esquematico ESP07

1. Esquematico con ESP01

El esquematico se divide en las secciones para el controlador, sensores y actuadores y fuente de alimentación.

El diseño para sensores y actuadores agrupa partes de ejercicios previos individuales para  Receptor, Emisor infrarrojo y sensor de temperatura/humedad, por lo que tenermos un diseño sumativo de experiencias previas.

1.1 Sensor

El sensor es infrarrojo , tipo TSOP1838, TSOP382, TSOP384, o alguna versión que incluya el circuito de demodulación.

La versión del sensor infrarojo con detección y demodulación simplifica el circuito a un pin digital configurado como entrada en el módulo de control a usar, además de alimentación de energía Vcc y Gnd.

En un control remoto IR convencional, cuando se presiona una tecla de control, se genera un código único que es detectado y copiado en el dispositivo con el sensor.

La temperatura y humedad es información complementaria para operar un acondicionador de aire, por lo que se añade otro sensor al dispositivo para sensar temperatura y Humedad.

Los pines usados para cada sensor y actuador se encuentran etiquetados en el esquemático.

1.2 Actuador

Para enviar la señal del control al artefacto (COSA: acondicionador de aire), se emplea un LED infrarrojo semejante al mostrado en la figura.

Considere que algunos LEDs infrarojos son tambien vienen con empaquetado transparente. La operación del LED se puede comprobar al conectarlo como un LED normal y observarlo con la cámara de un teléfono móvil donde se observa la luminocidad.

1.3 Controlador

Se desarrolla centrado en ESP8266 modelo ESP-07 que incluye pines acondicionados para sensores infrarojo. La activación del módulo se realiza de acuerdo a lo descrito en el manual del módulo, tambien descrita en la sección «Módulos» ESP8266 versión ESP-07.

En el esquema se observa que el reinicio del dispositivo se controla con la botonera «Reset» que cambia el pin a estado BAJO (GND); el estado predeterminado es ALTO por medio de R1 y C1 minimiza los rebotes del pulsador.

1.3.1 Modo Ejecución

La operación predeterminada es «Ejecutar Programa» por medio de R3 hacia estado ALTO (pullup HIGH). Es posible reiniciar la ejecución usando la botonera Reset.

1.3.2 Modo Cargar Programa

Para «Cargar Programa» tambien se usa una botonera etiquetada como «PROG» hacia estado BAJO (GND), el programa se transfiere con un módulo USB-TTL al computador desde el Arduino IDE. Los móduloes ESP-07 y USB-TTL se conectan mediante a los pines RX-TX-GND intercambiando entre ellos RX con TX.

Para iniciar la subida del programa desde Arduino IDE, se presionan en conjunto los botones RESET y PROG, soltando luego de 1 segundo solamente RESET y comenzará la subida del archivo. Para minimizar los rebotes del pulsador, Reset se conecta con R1 hacia estado predeterminado ALTO y se complementa con C1 .

La configuración se completa manteniendo el estado de GPIO2 en estado ALTO (pullup HIGH) con R2 y el pin de CH_PD a estado ALTO mediante R4.

1.4 Fuente DC

Se conforma con el Regulador d 110VAC  a 5VDC seguidi por el Regulador de 5VDC a 3.3VDC usando el módulo AMS1117. Se usan dos voltajes, 5V y 3.3V, en conocimiento que el uso de los sensores de temperatura DHT11 funcionan mejor a 5V (Ver referencia).

Los componentes usados o sus componentes alternos se describen en la sección de Fuentes de Alimentación para Módulos.

http://blog.espol.edu.ec/edelros/fuente-de-alimentacion-a-3-3vdc/


2. Ensamble en Protoboard

Para pruebas y ajustes, se ensamblan las partes en un protoboard teniendo como guía el diagrama del circuito del punto anterior.

3. Circuito impreso – PCB

El diseño se ha realizado en dos placas por flexibilidad de ensamble. La placa de fuente de alimentación se puede reemplazar por un cargador USB, conectando a la primera placa del dispositivo a los conetores +5VDC-.

Observe la polaridad al conectar los pines para el sensor y emisor infrarrojos.

Para el archivo de producción de placa, escribir al email de contacto al final de la página.

Alternativas durante el proceso de desarrollo

Durante el desarrollo del prototipo y como comprobación de distribución de espacio entre los componentes se usan placas perforadas para circuito impreso de 5×7 cm.

El cableado previo permite como ejercicio visualizar mejoras al recorrido de las pistas.

Referencias: [SOLVED] DHT11/DHT22 – Failed to read from DHT sensor.  https://randomnerdtutorials.com/solved-dht11-dht22-failed-to-read-from-dht-sensor/

2.4 IoT WiFi Actuador Tomacorriente: MQTT-HA

Esta es la última sección a realizar, pues se supone que tiene listo el dispositivo, construido y operativas las partes: Dispositivo y Broker.

El objetivo es incorporar dispositivo Interruptor-Tomacorriente en el broker MQTT y observar los resultados.

Se plantea observar los estados del dispositivo en dos formas:

  • Desde un navegador en la página local de Home-Assistant
  • Desde una consola conectando al servidor MQTT

1. Incorporar el dispositivo en Home Assistant

Se requiere modificar el archivo configuration.yaml en el raspberry.

Se puede realizar en forma local desde el raspberry que tiene monitor, teclado y mouse conectado, y editar el archivo que se encuentra en el directorio:

 /home/homeassistant/.homeassistant/configuration.yaml

La otra forma es conectarse via remota por medio de una sesión ssh. Requiere dirección, usuario y password. Los detalles se dan en la sección Raspberry.

En el archivo se añade los datos del dispositivo interruptor-tomacorriente, que en el caso actual para pruebas se identifica como una luminaria (light).

El sensor trabaja con MQTT, se le asigna un nombre más sencillo de reconocer como «oficina luz 1.

Se complementa con la instrucción de control para el dispositivo (command_topic) identificada en el formato: «oficina/luz1/switch».

 

light:
  - platform: mqtt
    name: 'oficina_luz1'
    state_topic: 'oficina/luz1/estado'
    command_topic: 'oficina/luz1/cambia'
    optimistic: false

1.2  Monitoreo desde MQTT

Para monitorear señal desde consola Raspberry usando MQTT, usar la instrucción:

mosquitto_sub -h 192.168.10.100 -t oficina/luz1/estado

2.3 IoT WiFi Actuador Tomacorriente: Archivo.ino

1. Instrucciones en Arduino IDE

Como la versión del ESP8266-01 no dispone de muchos pines de trabajo, se define el uso de los pines como:

  • monitor de operación del dispositivo: LED interno, GPIO1 (TXD)
  • control Actuador en GPIO2, pin 3, que es usado para la modo de operación al iniciar el dispositivo. Luego de iniciado se lo puede reconfigurar.

Por el uso en operación de los pines de comunicación Serial (GPIO1 y GPIO3) se descartan las lineas Serial.print() convirtiendolas en comentarios «//».

El diseño realizado permite conectar un módulo USB-TTL a la placa PCB. Revise la configuración de las botoneras Reset, PROG y los Jumpers para realizar la carga del archivo.ino.

Si la subida del archivo.ino al módulo ESP01  se realiza fuera de la placa PCB revise nuevamente la configuración de PCB para que trabaje en modo «Ejecutar» luego de insertar el módulo ESP01.

2. Funciones repetitivas

Para las acciones repetitivas como la conexión a WIFI y comunicación por MQTT se realizan en funciones para simplificar las instrucciones en la configuración inicial (setup) y la ejecución principal (loop).

Al inicio se definen las librerías y los valores para la conexión WIFI y los datos para comunicarse con el servidor MQTT-Mosquitto implementado en el Raspberry. Revisar de ser necesario al sección Broker.

2.1 función para actuador

Para procesar las instrucciones enviadas por el Broker en MQTT se añade la función callback().

Para el control del Relé se usa la función ACTUADORactivaestado() que realiza acciones semejantes a la de activar el monitor LED, y permite en futuro mantener separadas las acciones sobre el ACTUADOR o Relé.)

/* ESP8266 Interruptor AC. edelros@espol.edu.ec
 *  Sensor-Actuador Binario, control de un Relay con Tomacorriente o foco.
 *  Para usar, actualice las secciones de:
 *  - WIFI:Router, MQTT:Servidor, MQTT:Dispositivo
 *  ESP-01 al usar GPIO1 y GPIO3,(Tx,Rx), NO USE Serial.print()
*/
#include <ESP8266WiFi.h>
#include <PubSubClient.h>

// WIFI: conexión a Router
char* ssid = "iotirni19";
char* password = "anera2018";

// MQTT: Servidor
char* MQTT_IP = "192.168.10.100";
uint16_t MQTT_puerto = 1883;
char* MQTT_usuario = "usuarioprueba";
char* MQTT_contrasena = "usuarioclave";

// MQTT: Dispositivo Interruptor
char* MQTT_ID = "oficina_luz1";
char* MQTT_TOPIC = "oficina/luz1/estado";
char* MQTT_COMMAND = "oficina/luz1/cambia";
char MQTT_SensorEstado[10] = "OFF";
char MQTT_ActuadorEstado[10] = "OFF";
volatile boolean mqtt_desconectado = true;

char* sensor_ON  = "ON";
char* sensor_OFF = "OFF";

// Actuador Tomacorriente-Luz
const uint8_t actuador_pin = 3;
volatile boolean actuador_estado = false;
volatile boolean actuador_bandera = true;

// LED monitor //interno: ESP01-pin=1, ESP07-pin=2
const uint8_t LED_pin=0;
const uint8_t LED_actuador = 2;

// Clientes WiFi y MQTT
WiFiClient wifiClient;
PubSubClient mqttclient(wifiClient);

void setup() {
  // ACTUADOR Tomacorriente
  pinMode(actuador_pin, OUTPUT);
  pinMode(LED_actuador, OUTPUT);
  
  // LED monitor, Enciende en LOW
  pinMode(LED_pin, OUTPUT);

  // conexión WIFI y MQTT
  inicia_wifi();
  if (WiFi.status() == WL_CONNECTED){
    inicia_mqtt();
    }
  }

void loop() {
  // Revisa cambios en interruptor
  if (actuador_bandera){
    ACTUADORactivaestado();
    if (mqttclient.connected()){
      publica_estado();
      }
    actuador_bandera = false;
    }
  yield(); // procesa wifi
  if (WiFi.status() != WL_CONNECTED){
    inicia_wifi();
    }else{
      if (!mqttclient.connected()){
        mqtt_desconectado = true;
        inicia_mqtt();
      }else{
        mqttclient.loop();
        if (mqtt_desconectado==true){
          publica_estado();
          mqtt_desconectado==false;
          }
        }
    }
    yield(); // procesa wifi
}

// Actuador activar estado
void ACTUADORactivaestado(){
  if (actuador_estado){
      // ACTUADOR ACTIVA EN LOW
      // LED actuador ilumina en apagado
      digitalWrite(actuador_pin, LOW);
      digitalWrite(LED_actuador, HIGH);
    }else{
      digitalWrite(actuador_pin, HIGH);
      digitalWrite(LED_actuador, LOW);
    }
}

// Publicar el estado del dispositivo
void publica_estado() {
  if (actuador_estado){
    snprintf (MQTT_ActuadorEstado,10, sensor_ON);
  }else{
    snprintf (MQTT_ActuadorEstado,10, sensor_OFF);
  }
  mqttclient.publish(MQTT_TOPIC,MQTT_ActuadorEstado,true); 
  mqttclient.subscribe(MQTT_COMMAND);
}

void inicia_wifi(){
  int intentos = 20;
  int cuenta = 0;
  WiFi.begin(ssid, password);
  
  while ((WiFi.status() != WL_CONNECTED) && (cuenta<=intentos)){
    cuenta = cuenta+1;
    // Parpadeo de Monitor enciende en LOW
    digitalWrite(LED_pin, LOW);
    delay(250);
    digitalWrite(LED_pin, HIGH);
    delay(250);
    }
  }

void inicia_mqtt(){
  int intentos = 4;
  int cuenta = 0;
  mqttclient.setServer(MQTT_IP, MQTT_puerto);
  mqttclient.connect(MQTT_ID, MQTT_usuario, MQTT_contrasena);
  mqttclient.setCallback(callback);
  
  while (!mqttclient.connected() && (cuenta<=intentos)) {
    cuenta = cuenta + 1;
    // Parpadeo de Monitor enciende en LOW
    digitalWrite(LED_pin, LOW);
    delay(600);
    digitalWrite(LED_pin, HIGH);
    delay(400);
    }
  if (mqttclient.connected()){
      publica_estado();
  }
  }

// llega mensaje MQTT
void callback(char* p_topic, byte* p_payload, unsigned int p_length) {
  // convierte a texto
  String payload;
  for (uint8_t i = 0; i < p_length; i++) {
    payload.concat((char)p_payload[i]);
    }
  // revisa mensaje por topico
  if (String(MQTT_COMMAND).equals(p_topic)) {
    if (payload.equals(String(sensor_ON))) {
      if (actuador_estado != true) {
        actuador_estado = true;
        }
      }
    if (payload.equals(String(sensor_OFF))) {
      if (actuador_estado != false) {
          actuador_estado = false;
        }
      }
    actuador_bandera = true;
    }
  }

2.2 IoT WiFi Actuador Tomacorriente: Esquemático ESP01

1. Esquemático con ESP01

El esquemático se divide en varias secciones mostradas en la figura y descritas a continuación.

1.1 Actuador

Para controlar el estado de un tomacorriente y la carga conectada se usa un relé.

La capacidad de carga del relé determina la capacidad de carga en Amperios del dispositivo, para el prototipo se usa el más básico de los relés controlados por 5 VDC y contactor a 110VAC nominalmente a 10A. No se usará la capacidad máxima del relé.

Para la operación del Relé se usa un optoacoplador que permite acoplar la salida digital del ESP8266 con la corriente demandada por la operación del Relé de aproximadamente 10mA.

El relé se activa con una señal de control de 5VDC que es diferente al voltaje de operación del controlador de 3.3VDC. La diferencia de voltajes se maneja por medio de un optoacoplador como una simplificación para separar los circuitos. Dado que la corriente del optoacoplador disponible no es suficiente para manejar el relé, se usa un Transistor NPN para impulsar la bobina del relé.

El relé tiene dos salidas en estado normalmente cerrado (NC)y la otra normalmente abierto (NO). La alimentación de estas salidas se realiza por medio de la línea de alimentación, por lo que éste dispositivo tienen un conector de 3 entradas para cada actuador. Seleccione la salida que sea de interés para el control del aparato (COSA) con el dispositivo.

1.2 Controlador

El pin para el actuador es GPIO3, RXD, que también se usó con el sensor magnético de puerta -ventana, configurado como salida (OUTPUT).

Se usa un LED monitor para el estado del interruptor/actuador en GPIO2 y un LED monitor para mostrar el estado durante conexión a la red en GIPO0. El diseño considera mantener GPIO0 y GPIO2 en el estado ALTO al inicio del dispositivo, luego establecer el modo de salida (OUTPUT, INPUT) en las instrucciones de configuración (setup()).

El reinicio del dispositivo se controla con la botonera «Reset» al cambiar el pin a estado BAJO (GND). El estado predeterminado es ALTO por medio de R1 y C1 minimiza los rebotes del pulsador.

La placa del circuito permite solo el estado de operación del ESP-01, la programación del módulo ESP-01 se debe realizar fuera del tablero. Revise la opción de programar con la «Conexión USB-TTL».

La activación del módulo se realiza de acuerdo a lo descrito en el manual del módulo. Revisar en la sección «Módulos» ESP8266 versión ESP-01.

1.3 Fuente DC

Conformada por el Regulador d 110VAC  a 5VDC, y el Regulador de 5VDC a 3.3VDC usando el módulo AMS1117.

Los componentes usados o sus sus componentes alternos se describen en la sección de Fuentes de Alimentación para Módulos.

http://blog.espol.edu.ec/edelros/fuente-de-alimentacion-a-3-3vdc/


2. Ensamble en Protoboard

Para probar el circuito se ensambla en un protoboard teniendo como guía el diagrama del circuito del punto anterior.

Para el desarrollo de la placa se condideró pasar al siguiente dispositivo, al combinar un interruptor con un tomacorriente que requieren un sensor y un actuador para trabajar en conjunto.


3. Circuito impreso – PCB

3.1 PCB de 4.5×4.5cm. Ocupa el menor espacio posible considerando el tamaño de los componentes.

 

3.2 Placa de 5×7. Usa el espacio y partes distribuidas considerando el tamaño de las placas perforadas para realizar prototipos. Es la versión simplificada del prototipo de interruptor que controla un tomacorriente o foco.